Vba delete và add sheet trong excel

Trong một file Excel có thể tạo nhiều Sheet làm việc, nhưng bạn chỉ cần dùng một hay một số Sheet và không cần các Sheet còn lại. Với một vài Sheet thì có thể dùng cách xóa thủ công nhưng số lượng vài chục hay vài trăm Sheet thì nên sử dụng câu lệnh để thực hiện công việc này sẽ tiết kiệm thời gian và công sức đáng kể.

Xem bài học trước

>> VBA Excel Cấp Tốc Bài 1 - Lọc Dữ Liệu Nhiều Điều Kiện Với Advanced Filter

>> VBA Excel Cấp Tốc Bài 2 - In Bảng Cửu Chương

>> VBA Excel Cấp Tốc Bài 3 - In Ấn Nhanh Hàng Loạt

Video hướng dẫn

Mở Visual Basic

Mở Visual Basic để code những câu lệnh thực hiện việc xóa các Sheet không Active: Developer -> Visual Basic ->  chuột phải vào Sheet 1 -> Insert -> Module.

Code chương trình Xóa Sheet không Active

Cấu trúc của một chương trình vẫn là Sub sau đó đến tên chương trình enter phần kết trúc chương trình sẽ tự động sinh ra.

• Thực hiện khai báo một biến có tên là biến Worksheet với dòng lệnh:
• Sử dụng vòng lập For để quét tất cả các Sheet xem Sheet nào không phải là Sheet Active thì nó sẽ xóa đi, lệnh này với cú pháp là: For Each ws In ThisWorkbook.Sheets -> enter và Next để kết thúc vòng lặp.
• Tiếp tục If ws.Name <> ThisWorkbook.Activesheet.Name Then có nghĩa là nếu quét đến cái Sheet mà khác cái Sheet mình đang lựa chọn thao tác thì sẽ xóa đi -> enter và End If để kết thúc Điều kiện If.
• Bên trong hàm If viết câu lệnh nếu là khác thì xóa: Ws.Delete

Khi kích vào Run để chạy chương trình và sẽ hiện thông báo bạn thực sự có muốn xóa không bạn kích chọn Delete để xóa và thông báo cứ hiện lênh khi xóa mỗi Sheet.

Với số lượng rất nhiều Sheet nên không thể tích Delete mãi được thì mình sử dụng dòng lệnh: Application.DisplayAlerts = False và dòng lệnh: Application.DisplayAlerts = True hiện thông báo khi thực hiện lại xóa Sheet để tránh nhưng nguy hiểm cho người sử dụng sau.

Tạo Nút Nhấn Button

Phần này tùy vào nhu cầu hay chương trình của bạn có nên tạo Button hay không. Mình sẽ hướng dẫn cho các bạn cần tạo: Developer -> Insert -> chọn hình giữ chuột và kéo -> tích vào Macro mà bạn muốn gán cho Button -> ok.

Đoạn code VBA của chương trình xóa Sheets không Active:

Sub Xoa_sheet()
Dim ws As Worksheet
Application.DisplayAlerts = False
For Each ws In ThisWorkbook.Sheets
    If ws.Name <> ThisWorkbook.ActiveSheet.Name Then
        ws.Delete
    End If
Next
Application.DisplayAlerts = True
End Sub

Xem bài tiếp theo

>> VBA Excel Cấp Tốc Bài 5 - Copy File Từ Một Thư Mục Sang Thư Mục Khác

This VBA Tutorial is accompanied by Excel workbooks containing the data and macros I use in the examples below. You can get immediate free access to these example workbooks by subscribing to the Power Spreadsheets Newsletter.

Use the following Table of Contents to navigate to the section you're interested in.

• Related VBA and Macro Tutorials
• #1: Delete Sheet by Position
  • VBA Code to Delete Sheet by Position
  • Process Followed by VBA Code to Delete Sheet by Position
  • VBA Statement Explanation
  • Macro Example to Delete Sheet by Position
  • Effects of Executing Macro Example to Delete Sheet by Position
• #2: Delete Active Sheet
  • VBA Code to Delete Active Sheet
  • Process Followed by VBA Code to Delete Active Sheet
  • VBA Statement Explanation
  • Macro Example to Delete Active Sheet
  • Effects of Executing Macro Example to Delete Active Sheet
• #3: Delete Sheet by Name
  • VBA Code to Delete Sheet by Name
  • Process Followed by VBA Code to Delete Sheet by Name
  • VBA Statement Explanation
  • Macro Example to Delete Sheet by Name
  • Effects of Executing Macro Example to Delete Sheet by Name
• #4: Delete Sheet Without Prompt or Warning
  • VBA Code to Delete Sheet Without Prompt or Warning
  • Process Followed by VBA Code to Delete Sheet Without Prompt or Warning
  • VBA Statement Explanation
  • Macro Example to Delete Sheet Without Prompt or Warning
  • Effects of Executing Macro Example to Delete Sheet Without Prompt or Warning
• #5: Delete Sheet if it Exists
  • VBA Code to Delete Sheet if it Exists
  • Process Followed by VBA Code to Delete Sheet if it Exists
  • VBA Statement Explanation
  • Macro Example to Delete Sheet if it Exists
  • Effects of Executing Macro Example to Delete Sheet if it Exists
• #6: Delete Multiple Sheets
  • VBA Code to Delete Multiple Sheets
  • Process Followed by VBA Code to Delete Multiple Sheets
  • VBA Statement Explanation
  • Macro Example to Delete Multiple Sheets
  • Effects of Executing Macro Example to Delete Multiple Sheets
• References to VBA Constructs Used in this VBA Tutorial

Related VBA and Macro Tutorials

The following VBA and macro tutorials may help you better understand and implement the contents below:

• General VBA constructs and structures:
  • Learn about commonly-used VBA terms here.
  • Learn how to work with the Visual Basic Editor (VBE) here.
  • Learn how to create and work with VBA Sub procedures here.
  • Learn how to work with object methods here.
  • Learn how to declare and work with variables here.
  • Learn how to work with data types here.
  • Learn how to work with arrays here.
• Practical VBA applications and macro examples:
  • Learn other operations you can carry out when working with Excel worksheets here.

You can find additional VBA and Macro Tutorials in the Archives.

#1: Delete Sheet by Position

VBA Code to Delete Sheet by Position

To delete a sheet by its position using VBA, use a statement with the following structure:

Sheets(SheetIndex).Delete

Process Followed by VBA Code to Delete Sheet by Position

VBA Statement Explanation

1. Item: Sheets.
   • VBA Construct: Workbook.Sheets property.
   • Description: The Workbook.Sheets property returns a Sheets collection representing all the sheets within the workbook you deal with. Identify a single object from this Sheets collection by specifying the appropriate index number (SheetIndex).

     When deleting a worksheet, you can work with the Workbook.Worksheets property. Workbook.Worksheets represents a Sheets collection representing all worksheets within the workbook you deal with.

     When deleting a chart sheet, you can work with the Workbook.Charts property. Workbook.Charts returns a Sheets collection representing all chart sheets within the workbook you deal with.

2. Item: SheetIndex.
   • VBA Construct: Index parameter/number of the sheet you want to delete.
   • Description: The Index parameter/number of a sheet allows you to identify a single object (worksheet or chart sheet) from the Sheets collection you work with.

     The Index parameter/number represents the position of the sheet, worksheet or chart sheet in the tab bar of the workbook you deal with, from left to right. For example, 1 is the first (leftmost) sheet/worksheet/chart sheet.

     When specifying the Index parameter/number, consider the following:

     • The count usually includes hidden sheets/worksheets/chart sheets as well.
     • If you're working with the Workbook.Worksheets property, the count includes worksheets but not chart sheets.
     • If you're working with the Workbook.Charts property, the count includes chart sheets but not worksheets.

     If you explicitly declare a variable to represent SheetIndex, use the Long data type.

3. Item: Delete.
   • VBA Construct: Worksheet.Delete method or Chart.Delete method.
   • Description: The Delete method deletes the object (worksheet or chart sheet) you identify with Sheets(SheetIndex).

     When you delete a sheet with the Delete method, Excel usually displays (by default) a dialog box asking the user to confirm the deletion. Please refer to the appropriate section below to delete a sheet with no prompt.

Macro Example to Delete Sheet by Position

The following macro deletes the first sheet (Sheets(mySheetIndex)) in the workbook where the macro is stored (ThisWorkbook). The macro suppresses the prompt that asks the user to confirm the sheet deletion (Application.DisplayAlerts = False).

Sub deleteSheet()

    'Source: https://powerspreadsheets.com/
    'For further information: https://powerspreadsheets.com/excel-vba-delete-sheet/

    'declare variable to hold index number of sheet you want to delete
    Dim mySheetIndex As Long

    'specify index number of sheet you want to delete
    mySheetIndex = 1

    'suppress the dialog box that asks the user to confirm the sheet deletion
    Application.DisplayAlerts = False

    'identify sheet you want to delete, and delete it
    ThisWorkbook.Sheets(mySheetIndex).Delete

    're-enable the display of alerts and messages
    Application.DisplayAlerts = True

End Sub

Effects of Executing Macro Example to Delete Sheet by Position

The following GIF illustrates the results of executing the macro example. The first sheet in the workbook (Sheet1) is deleted.

#2: Delete Active Sheet

VBA Code to Delete Active Sheet

To delete the active sheet with VBA, use a statement with the following structure:

ActiveSheet.Delete

Process Followed by VBA Code to Delete Active Sheet

VBA Statement Explanation

1. Item: ActiveSheet.
   • VBA Construct: Application.ActiveSheet property.
   • Description: The Application.ActiveSheet property returns an object representing the active sheet.
2. Item: Delete.
   • VBA Construct: Worksheet.Delete method or Chart.Delete method.
   • Description: The Delete method deletes the object (worksheet or chart sheet) returned by ActiveSheet (the active sheet).

     When you delete a sheet with the Delete method, Excel usually displays (by default) a dialog box asking the user to confirm the deletion. Please refer to the appropriate section below to delete a sheet with no prompt.

Macro Example to Delete Active Sheet

The following macro deletes the active sheet (ActiveSheet). The macro suppresses the prompt that asks the user to confirm the sheet deletion (Application.DisplayAlerts = False).

Sub deleteActiveSheet()

    'Source: https://powerspreadsheets.com/
    'For further information: https://powerspreadsheets.com/excel-vba-delete-sheet/

    'suppress the dialog box that asks the user to confirm the sheet deletion
    Application.DisplayAlerts = False

    'identify active sheet, and delete it
    ActiveSheet.Delete

    're-enable the display of alerts and messages
    Application.DisplayAlerts = True

End Sub

Effects of Executing Macro Example to Delete Active Sheet

The following GIF illustrates the results of executing the macro example. The active sheet (Sheet2) is deleted.

#3: Delete Sheet by Name

VBA Code to Delete Sheet by Name

To delete a sheet by name using VBA, use a statement with the following structure:

Sheets(SheetName).Delete

Process Followed by VBA Code to Delete Sheet by Name

VBA Statement Explanation

1. Item: Sheets.
   • VBA Construct: Workbook.Sheets property.
   • Description: The Workbook.Sheets property returns a Sheets collection representing all the sheets within the workbook you deal with. Identify a single object from this Sheets collection by specifying the appropriate name (SheetName).

     When deleting a worksheet, you can work with the Workbook.Worksheets property. Workbook.Worksheets represents a Sheets collection representing all worksheets within the workbook you deal with.

     When deleting a chart sheet, you can work with the Workbook.Charts property. Workbook.Charts returns a Sheets collection representing all chart sheets within the workbook you deal with.

2. Item: SheetName.
   • VBA Construct: Name of the sheet you want to delete.
   • Description: The name of a sheet allows you to identify a single object (worksheet or chart sheet) from the Sheets collection you work with.

     For these purposes, the sheet name is that displayed in the tab of the worksheet or chart sheet. If you explicitly declare a variable to represent SheetName, use the String data type.

3. Item: Delete.
   • VBA Construct: Worksheet.Delete method or Chart.Delete method.
   • Description: The Delete method deletes the object (worksheet or chart sheet) you identify with Sheets(SheetName).

     When you delete a sheet with the Delete method, Excel usually displays (by default) a dialog box asking the user to confirm the deletion. Please refer to the appropriate section below to delete a sheet with no prompt.

Macro Example to Delete Sheet by Name

The following macro deletes the sheet named “delete Sheet” (Sheets(mySheetName)) in the workbook where the macro is stored (ThisWorkbook). The macro suppresses the prompt that asks the user to confirm the sheet deletion (Application.DisplayAlerts = False).

Sub deleteSheetByName()

    'Source: https://powerspreadsheets.com/
    'For further information: https://powerspreadsheets.com/excel-vba-delete-sheet/

    'declare variable to hold name of sheet you want to delete
    Dim mySheetName As String

    'specify name of sheet you want to delete
    mySheetName = "delete sheet"

    'suppress the dialog box that asks the user to confirm the sheet deletion
    Application.DisplayAlerts = False

    'identify sheet you want to delete, and delete it
    ThisWorkbook.Sheets(mySheetName).Delete

    're-enable the display of alerts and messages
    Application.DisplayAlerts = True

End Sub

Effects of Executing Macro Example to Delete Sheet by Name

The following GIF illustrates the results of executing the macro example. The sheet named “delete sheet” is deleted.

#4: Delete Sheet Without Prompt or Warning

VBA Code to Delete Sheet Without Prompt or Warning

To delete a sheet without Excel displaying the usual prompt (warning) with VBA, use a macro with the following statement structure:

Application.DisplayAlerts = False
Sheets(SheetName).Delete
Application.DisplayAlerts = True

Process Followed by VBA Code to Delete Sheet Without Prompt or Warning

VBA Statement Explanation

Lines #1 and #3: Application.DisplayAlerts = False | Application.DisplayAlerts = True

1. Item: Application.DisplayAlerts.
   • VBA Construct: Application.DisplayAlerts property.
   • Description: The Application.DisplayAlerts property allows you to specify whether Excel displays alerts and messages while the macro is running. When you delete a sheet, the main alert that Excel usually displays (and you want to handle) is the dialog box that prompts the user to confirm the sheet deletion.

     The default value of the Application.DisplayAlerts property is True. In such cases, Excel displays the dialog box prompting the user to confirm the sheet deletion.

2. Item: False.
   • VBA Construct: New property value of Application.DisplayAlerts property.
   • Description: When you delete a sheet, you can suppress the dialog box that prompts the user to confirm the sheet deletion, by setting the Application.DisplayAlerts property to False.

     When you set Application.DisplayAlerts to False and Excel requires a response, Excel chooses the default response. When you delete a sheet, the default response to the dialog box prompting the user to confirm the sheet deletion is “Delete”. This results in Excel deleting the sheet.

3. Item: True.
   • VBA Construct: New property value of Application.DisplayAlerts property.
   • Description: The default value of the Application.DisplayAlerts property is True. This results in Excel displaying alerts and messages while a macro is running.

     Generally, when you set Application.DisplayAlerts to False, Excel sets the property back to True upon finishing macro execution. Since there are exceptions (such as executing cross-process code), you can explicitly set Application.DisplayAlerts back to True after deleting the sheet.

Line #2: Sheets(SheetName).Delete

1. Item: Sheets.
   • VBA Construct: Workbook.Sheets property.
   • Description: The Workbook.Sheets property returns a Sheets collection representing all the sheets within the workbook you deal with. Identify a single object from this Sheets collection by specifying the appropriate name (SheetName).

     When deleting a worksheet, you can work with the Workbook.Worksheets property. Workbook.Worksheets represents a Sheets collection representing all worksheets within the workbook you deal with.

     When deleting a chart sheet, you can work with the Workbook.Charts property. Workbook.Charts returns a Sheets collection representing all chart sheets within the workbook you deal with.

2. Item: SheetName.
   • VBA Construct: Name of the sheet you want to delete.
   • Description: The name of a sheet allows you to identify a single object (worksheet or chart sheet) from the Sheets collection you work with.

     For these purposes, the sheet name is that displayed in the tab of the worksheet or chart sheet. If you explicitly declare a variable to represent SheetName, use the String data type.

3. Item: Delete.
   • VBA Construct: Worksheet.Delete method or Chart.Delete method.
   • Description: The Delete method deletes the object (worksheet or chart sheet) you identify with Sheets(SheetName).

Macro Example to Delete Sheet Without Prompt or Warning

The following macro deletes the sheet named “delete sheet no prompt” (Sheets(mySheetName)) in the workbook where the macro is stored (ThisWorkbook) without displaying the prompt that asks the user to confirm the sheet deletion (Application.DisplayAlerts = False).

Sub deleteSheetNoPrompt()

    'Source: https://powerspreadsheets.com/
    'For further information: https://powerspreadsheets.com/excel-vba-delete-sheet/

    'declare variable to hold name of sheet you want to delete
    Dim mySheetName As String

    'specify name of sheet you want to delete
    mySheetName = "delete sheet no prompt"

    'suppress the dialog box that asks the user to confirm the sheet deletion
    Application.DisplayAlerts = False

    'identify sheet you want to delete, and delete it
    ThisWorkbook.Sheets(mySheetName).Delete

    're-enable the display of alerts and messages
    Application.DisplayAlerts = True

End Sub

Effects of Executing Macro Example to Delete Sheet Without Prompt or Warning

The following GIF illustrates the results of executing the macro example. The sheet named “delete sheet no prompt” is deleted without a prompt or warning.

#5: Delete Sheet if it Exists

VBA Code to Delete Sheet if it Exists

To delete a sheet if it exists with VBA, use a macro with the following statement structure:

On Error Resume Next
Sheets(SheetName).Delete
On Error GoTo 0

Process Followed by VBA Code to Delete Sheet if it Exists

VBA Statement Explanation

Line #1: On Error Resume Next

1. Item: On Error Resume Next.
   • VBA Construct: On Error Resume Next statement.
   • Description: The On Error Resume Next statement specifies that, if an error occurs, control goes to the statement immediately following the statement where the error occurs. Execution continues at that statement that follows that where the error occurs.

     “Sheets(SheetName).Delete” usually returns run-time error 9 (subscript out of range) when the sheet identified by Sheets(SheetName) doesn't exist. Without the On Error Resume Next statement, such error results in Excel displaying an error message and stopping macro execution.

     Therefore:

     • If the sheet named SheetName exists, Excel deletes the sheet as specified by “Sheets(SheetName).Delete”.
     • If the sheet named SheetName doesn't exist, execution of the macro continues on the statement following “Sheet(SheetName).Delete”. Due to the On Error Resume Next statement, Excel handles the run-time error.

Line #2: Sheets(SheetName).Delete

1. Item: Sheets.
   • VBA Construct: Workbook.Sheets property.
   • Description: The Workbook.Sheets property returns a Sheets collection representing all the sheets within the workbook you deal with. Identify a single object from this Sheets collection by specifying the appropriate name (SheetName).

     When deleting a worksheet, you can work with the Workbook.Worksheets property. Workbook.Worksheets represents a Sheets collection representing all worksheets within the workbook you deal with.

     When deleting a chart sheet, you can work with the Workbook.Charts property. Workbook.Charts returns a Sheets collection representing all chart sheets within the workbook you deal with.

2. Item: SheetName.
   • VBA Construct: Name of the sheet you want to delete.
   • Description: The name of a sheet allows you to identify a single object (worksheet or chart sheet) from the Sheets collection you work with.

     For these purposes, the sheet name is that displayed in the tab of the worksheet or chart sheet. If you explicitly declare a variable to represent SheetName, use the String data type.

3. Item: Delete.
   • VBA Construct: Worksheet.Delete method or Chart.Delete method.
   • Description: The Delete method deletes the object (worksheet or chart sheet) you identify with Sheets(SheetName).

     When you delete a sheet with the Delete method, Excel usually displays (by default) a dialog box asking the user to confirm the deletion. Please refer to the appropriate section above to delete a sheet with no prompt.

Line #3: On Error GoTo 0

1. Item: On Error GoTo 0.
   • VBA Construct: On Error GoTo 0 statement.
   • Description: The On Error GoTo 0 statement disables the error handling specified by the On Error Resume Next statement. If you omit the On Error GoTo 0 statement, Excel generally disables the error handler automatically when exiting the procedure.

Macro Example to Delete Sheet if it Exists

The following macro deletes the sheet named “delete sheet if exists” (Sheets(mySheetName)) in the workbook where the macro is stored (ThisWorkbook), if such sheet exists. If the sheet doesn't exist, the macro handles the error. The macro suppresses the prompt that asks the user to confirm the sheet deletion (Application.DisplayAlerts = False).

Sub deleteSheetIfExists()

    'Source: https://powerspreadsheets.com/
    'For further information: https://powerspreadsheets.com/excel-vba-delete-sheet/

    'declare variable to hold name of sheet you want to delete
    Dim mySheetName As String

    'specify name of sheet you want to delete
    mySheetName = "delete sheet if exists"

    'suppress the dialog box that asks the user to confirm the sheet deletion
    Application.DisplayAlerts = False

    'enable error handling to deal with error that occurs when (if) you try to delete a sheet that doesn't exist
    On Error Resume Next

    'identify sheet you want to delete, and delete it
    ThisWorkbook.Sheets(mySheetName).Delete

    'disable error handling
    On Error GoTo 0

    're-enable the display of alerts and messages
    Application.DisplayAlerts = True

End Sub

Effects of Executing Macro Example to Delete Sheet if it Exists

The following GIF illustrates the results of executing the macro example. The sheet named “delete sheet if exists” is deleted.

#6: Delete Multiple Sheets

VBA Code to Delete Multiple Sheets

To delete multiple sheets with VBA, use a statement with the following structure:

Sheets(Array(SheetsList)).Delete

Process Followed by VBA Code to Delete Multiple Sheets

VBA Statement Explanation

1. Item: Sheets.
   • VBA Construct: Workbook.Sheets property.
   • Description: The Workbook.Sheets property returns a Sheets collection representing all the sheets within the workbook you deal with. Identify a single object from this Sheets collection by specifying the appropriate name (SheetName).

     When deleting worksheets, you can work with the Workbook.Worksheets property. Workbook.Worksheets represents a Sheets collection representing all worksheets within the workbook you deal with.

     When deleting chart sheets, you can work with the Workbook.Charts property. Workbook.Charts returns a Sheets collection representing all chart sheets within the workbook you deal with.

2. Item: Array(…).
   • VBA Construct: Array function.
   • Description: The Array function returns a Variant containing an array.
3. Item: SheetsList.
   • VBA Construct: Argument list of Array function.
   • Description: A comma-delimited list of the values you assign to each of the array elements.

     You can generally identify specific objects from the Sheets collection you work with using an index number or the sheet name, as follows:

     • The index number represents the position of a sheet, worksheet or chart sheet in the tab bar of the workbook you deal with, from left to right. For example, 1 is the first (leftmost) sheet/worksheet/chart sheet.

       When specifying the Index parameter/number, consider the following:

       • The count usually includes hidden sheets/worksheets/chart sheets as well.
       • If you're working with the Workbook.Worksheets property, the count includes worksheets but not chart sheets.
       • If you're working with the Workbook.Charts property, the count includes chart sheets but not worksheets.
     • The sheet name is that displayed in the tab of the worksheet or chart sheet.
4. Item: Delete.
   • VBA Construct: Worksheet.Delete method or Chart.Delete method.
   • Description: The Delete method deletes the object (worksheets or chart sheets) you identify with Sheets(Array(SheetsList)).

     When you delete a sheet with the Delete method, Excel usually displays (by default) a dialog box asking the user to confirm the deletion. Please refer to the appropriate section above to delete a sheet with no prompt.

Macro Example to Delete Multiple Sheets

The following macro deletes (i) the first 2 sheets, and (ii) the sheets named “delete multiple sheets 1” and “delete multiple sheets 2” (Sheets(mySheetNames)), in the workbook where the macro is stored (ThisWorkbook). The macro suppresses the prompt that asks the user to confirm the sheet deletion (Application.DisplayAlerts = False).

Sub deleteMultipleSheets()

    'Source: https://powerspreadsheets.com/
    'For further information: https://powerspreadsheets.com/excel-vba-delete-sheet/

    'declare variable to hold Variant containing array whose elements are the index numbers or names of the sheets you want to delete
    Dim mySheetNames() As Variant

    'specify (using index numbers or names) the sheets you want to delete
    mySheetNames = Array(1, 2, "delete multiple sheets 1", "delete multiple sheets 2")

    'suppress the dialog box that asks the user to confirm the sheet deletion
    Application.DisplayAlerts = False

    'identify sheets you want to delete, and delete them
    ThisWorkbook.Sheets(mySheetNames).Delete

    're-enable the display of alerts and messages
    Application.DisplayAlerts = True

End Sub

Effects of Executing Macro Example to Delete Multiple Sheets

The following GIF illustrates the results of executing the macro example. The (i) the first 2 sheets (Sheet6 and Sheet7), and (ii) the sheets named “delete multiple sheets 1” and “delete multiple sheets 2”, are deleted.

References to VBA Constructs Used in this VBA Tutorial

Use the following links to visit the appropriate webpage in the Microsoft Developer Network:

1. Identify workbook containing sheets, worksheets or chart sheets to delete:
   • Application.ThisWorkbook property.
   • Application.ActiveWorkbook property.
   • Application.Workbooks property.
   • Workbook object.
2. Identify sheets, worksheets and chart sheets:
   • Workbook.Sheets property.
   • Application.ActiveSheet property.
   • Sheets object.
   • Workbook.Worksheets property.
   • Worksheet object.
   • Workbook.Charts property.
   • Chart object.
3. Delete sheets, worksheets and chart sheets:
   1. Worksheet.Delete method.
   2. Chart.Delete method.
4. Prevent Excel from displaying prompts or warnings when deleting a sheet, worksheet or chart sheet:
   • Application.DisplayAlerts property.
5. Handle errors:
   • On Error statement.
6. Create an array containing the names of several sheets, worksheets or chart sheets to delete:
   • Array function.
7. Work with variables and data types:
   • Dim statement.
   • = operator.
   • Data types:
     • Long data type.
     • String data type.
     • Variant data type.